Warning: the below article and script were created by a third party, not affiliated with LolKing, and is designed to modify your registry files. Do so at your own risk!


If you play League of Legends and use any third party tools (e.g. to record replays, enhance gameplay, etc.) then you have probably run into programs that ask for the path of your League of Legends directory. Fortunately, some programs can auto detect this using the Windows registry. However, if you have moved your League of Legends folder to another folder, reinstalled/upgraded Windows or used a registry cleaner in the past then its possible that your registry entries are corrupt. This means they either don’t exist or don’t point to the correct path.



To attempt a fix, download the attached .bat file (found at the bottom of this page), right click it and 'Run as Administrator'. Follow the on screen instructions and choose your system architecture (32 bit/64 bit) and enter the path to your LoL folder. If you do not know your system architecture (32 bit/64 bit) then run the program twice and use both options. To find the path to your LoL folder, you'll want to find it via File Explorer (it's most commonly C:\Riot Games\League of Legends):





Copy of the script being ran by the attached .bat file:


@echo off
setlocal enabledelayedexpansion
 
cls
echo ----------------------------------------------
echo LoL RADS Registry Fixer by PersianMG (https://mohammadg.com/)
echo ----------------------------------------------
 
:: Ask for 64bit or 32 bit
:getArch
set /p "targetArch=Are you on a 32bit or 64bit machine [enter 32 or 64]?: "
 
if %targetArch% NEQ 32 (
  if %targetArch% NEQ 64 (
    echo "Invalid architecture."
    goto getArch
  )
)
 
:: Get LoL Directory Path
:getPath
set /p "lolpath=What path is League of Legends installed in? [ie: C:\Riot Games\League of Legends]: "
 
:: Check for valid path
if ["%lolpath%"] == [] (
  echo Empty path is not allowed.
  goto getPath
)
 
if not exist "%lolpath%" (
  echo Path points to folder that does not exist.
  goto getPath
)
 
:: Add /rads to path
set lolpath=%lolpath%\RADS
echo Key values will be set to the following RADS path: %lolpath% & echo.
 
:: Add 32 bit registry keys
if %targetArch% EQU 32 (
 
  echo Fixing key: HKCR\VirtualStore\MACHINE\SOFTWARE\Riot Games\RADS
  reg add "HKCR\VirtualStore\MACHINE\SOFTWARE\Riot Games\RADS" /v LocalRootFolder /t REG_SZ /d "%lolpath%" /f & echo.
 
  echo Fixing key: HKCU\SOFTWARE\Riot Games\RADS
  reg add "HKCU\SOFTWARE\Riot Games\RADS" /v LocalRootFolder /t REG_SZ /d "%lolpath%" /f & echo.
 
  echo Fixing key: HKLM\SOFTWARE\Riot Games\RADS
  reg add "HKLM\SOFTWARE\Riot Games\RADS" /v LocalRootFolder /t REG_SZ /d "%lolpath%" /f & echo.
)
 
:: Add 64 bit registry keys
if %targetArch% EQU 64 (
 
  echo Fixing key: HKCR\VirtualStore\MACHINE\SOFTWARE\Wow6432Node\Riot Games\RADS
  reg add "HKCR\VirtualStore\MACHINE\SOFTWARE\Wow6432Node\Riot Games\RADS" /v LocalRootFolder /t REG_SZ /d "%lolpath%" /f & echo.
 
  echo Fixing key: HKCU\SOFTWARE\Classes\VirtualStore\MACHINE\SOFTWARE\Wow6432Node\Riot Games\RADS
  reg add "HKCU\SOFTWARE\Classes\VirtualStore\MACHINE\SOFTWARE\Wow6432Node\Riot Games\RADS" /v LocalRootFolder /t REG_SZ /d "%lolpath%" /f & echo.
  
  echo Fixing key: HKCU\SOFTWARE\Riot Games\RADS
  reg add "HKCU\SOFTWARE\Riot Games\RADS" /v LocalRootFolder /t REG_SZ /d "%lolpath%" /f & echo.
  
  echo Fixing key: HKLM\SOFTWARE\Wow6432Node\Riot Games\RADS
  reg add "HKLM\SOFTWARE\Wow6432Node\Riot Games\RADS" /v LocalRootFolder /t REG_SZ /d "%lolpath%" /f & echo.
)
 
echo All keys fixed!
 
@pause


Credit for the above fix goes to Mohammad Ghasembeigi. Source: https://mohammadg.com